PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

pkgname=rpicam-apps
pkgver=1.4.3
pkgrel=1
pkgdesc="Camera utilities for the Raspberry Pi"
arch=('aarch64')
url='https://github.com/raspberrypi/rpicam-apps'
source=(
	"https://github.com/raspberrypi/rpicam-apps/releases/download/v${pkgver}/rpicam-apps-${pkgver}.tar.xz"
	"rpicam-apps.rules"
)
sha256sums=(
	"c5415249eb8216a5c7063d31c713ba84cac88103f65ae0dcf097f1839156102e"
	"4045e41e24d8c3e247b667a66bc9eee13918f599f464003dde25ca55ed7bb995"
)
depends=(
	boost
	libdrm
	libexif
	ffmpeg
	libcamera-rpi
	qt5-base
	qt5-tools
)
makedepends=(meson ninja)
optdepends=()

prepare()
{
	cd rpicam-apps-${pkgver}
	mkdir build
	arch-meson build \
		--buildtype=release \
		--wrap-mode default \
		-Denable_libav=true \
		-Denable_drm=true \
		-Denable_egl=true \
		-Denable_qt=true \
		-Denable_opencv=false \
		-Denable_tflite=false
}

build()
{
	cd rpicam-apps-${pkgver}
	meson compile -C build
}

package()
{
	install --mode=644 -D rpicam-apps.rules "${pkgdir}/etc/udev/rules.d/rpicam-apps.rules"
	cd rpicam-apps-${pkgver}
	DESTDIR="${pkgdir}" ninja -C build install
}