pkgname=rpicam-apps
pkgver=1.5.2
pkgrel=1
pkgdesc="Camera utilities for the Raspberry Pi"
arch=('aarch64')
url='https://github.com/raspberrypi/rpicam-apps'
source=(
	"https://github.com/raspberrypi/rpicam-apps/archive/refs/tags/v${pkgver}.tar.gz"
	"rpicam-apps.rules"
	"rpicam-apps-1.4.3-outputfilename.patch"
)
sha256sums=(
	"7af81158e04f16af379d0804b939c817fee01e1510c1e11249f998a4f4600c8d"
	"4045e41e24d8c3e247b667a66bc9eee13918f599f464003dde25ca55ed7bb995"
	"1e53aa6ea95ded5b6e6d28bac35f53b5725c06a99ab4664e37e88869dfe2e698"
)
depends=(
	boost
	libdrm
	libexif
	ffmpeg
	libcamera-rpi
	qt6-base
	qt6-tools
)
makedepends=(meson ninja)
optdepends=()

prepare()
{
	cd rpicam-apps-${pkgver}
	patch -Np1 -i "${srcdir}/rpicam-apps-1.4.3-outputfilename.patch"
	mkdir build
	arch-meson build \
		--buildtype=release \
		--wrap-mode default \
		-Denable_libav=enabled \
		-Denable_drm=enabled \
		-Denable_egl=enabled \
		-Denable_qt=enabled \
		-Denable_opencv=disabled \
		-Denable_tflite=disabled \
		-Denable_hailo=disabled \
		-Denable_imx500=false
}

build()
{
	cd rpicam-apps-${pkgver}
	meson compile -C build
}

package()
{
	install --mode=644 -D rpicam-apps.rules "${pkgdir}/etc/udev/rules.d/rpicam-apps.rules"
	cd rpicam-apps-${pkgver}
	DESTDIR="${pkgdir}" ninja -C build install
}