# Maintainer: Stijn Buys <ingar@telenet.be>
# Contributor: Marc-Olivier Barre <mobarre-archlinux@snarchi.io>
# Contributor: Peter Strapp <peter@strapp.co.uk>

pkgname=libindi_3rdparty_libs
pkgver=2.1.1
pkgrel=1
pkgdesc="dependencies for INDI 3rd party drivers"
provides=("libindi_3rdparty-libs")
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL2.1)
arch=(x86_64 aarch64)
depends=(libvorbis libusb openal libnova libjpeg libindi libgphoto2 libftdi-compat libdc1394 limesuite libftdi cfitsio dcraw rtl-sdr gpsd ffmpeg zeromq cppzmq libindi=${pkgver})
makedepends=(cmake boost)
conflicts=()
source=("https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz")
sha256sums=("17ae94f77171887920f91a78e322de49e55cc24a068e86b1091fa50978d3a127")

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DFIRMWARE_INSTALL_DIR=/usr/lib/firmware \
    -DQHY_FIRMWARE_INSTALL_DIR=/usr/lib/firmware \
    -DBUILD_LIBS=On \
    -DWITH_TOUPBASE=On \
    ../indi-3rdparty-${pkgver}
  make -j$(nproc)
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
  cd "$pkgdir"
  sed -e 's|/lib/firmware|/usr/lib/firmware|' -i usr/lib/udev/rules.d/*.rules
  sed -e 's|/usr/lib/firmware/qhy|/usr/lib/firmware|' -i usr/lib/udev/rules.d/85-qhyccd.rules
  sed -e 's|-D $env{DEVNAME}|-p $env{BUSNUM},$env{DEVNUM}|' usr/lib/udev/rules.d/85-qhyccd.rules
  find usr/lib -type f -name "*.so.*" -exec chmod 755 {} \;
}