# Maintainer: Stijn Buys <ingar@telenet.be>
# Contributor: Marc-Olivier Barre <mobarre-archlinux@snarchi.io>
# Contributor: Peter Strapp <peter@strapp.co.uk>

# TODO
# 	create indi user and home directory
#	remove support for i686 and armv7h

pkgname=libindi_3rdparty
pkgver=2.1.4
pkgrel=1
pkgdesc="3rd party drivers for INDI, a distributed control protocol designed to operate astronomical instrumentation"
provides=("libindi_3rdparty")
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL2.1)
arch=(i686 x86_64 armv7h aarch64)
depends=(libvorbis libusb openal libnova libjpeg libindi libgphoto2 libftdi-compat libdc1394 cfitsio dcraw libftdi rtl-sdr gpsd ffmpeg libindi_3rdparty_libs=${pkgver})
makedepends=(cmake boost)
conflicts=()
source=(
	"https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz"
	"indiserver.conf"
	"indiserver.service"
	"indiserver_systemd"
)
sha256sums=(
	"e9ab43d08d09555d2c9d3c658d1bcc3130c3465a3afe2300995fba0d6e737080"
	"6784118f7826c563058711bc3336d877ca44e79cf8b7e5205ab00901b1892924"
	"995751458ff3143f5115f68a62343ead16afb225199353ce3894ae38b8ca396c"
	"6fde81d89414b41576ebe180088648fb433fa1606ea47408d8a19e5c1c99a1d9"
)
backup=(etc/indiserver.conf)

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DFIRMWARE_INSTALL_DIR=/usr/lib/firmware \
    -DBUILD_LIBS=Off \
    -DWITH_ASICAM=On \
    -DWITH_EQMOD=On \
    -DWITH_TOUPBASE=On \
    -DWITH_GPSD=On \
    ../indi-3rdparty-${pkgver}
  make -j$(nproc)
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
  
  cd "${pkgdir}"
  install -d "etc/"
  install -m 644 "${srcdir}/indiserver.conf" "etc/indiserver.conf"
 
  install -d "usr/lib/systemd/system/"
  install -m 644 "${srcdir}/indiserver.service" "usr/lib/systemd/system/indiserver.service"
  
  install -d "usr/bin/"
  install -m 755 "${srcdir}/indiserver_systemd" "usr/bin/indiserver_systemd"

  cp -a lib/* usr/lib/
  rm -rf lib/*
  rmdir lib
}