# Maintainer: Stijn Buys <ingar@telenet.be>
# Contributor: Marc-Olivier Barre <mobarre-archlinux@snarchi.io>
# Contributor: Peter Strapp <peter@strapp.co.uk>

pkgname=libindi_3rdparty
pkgver=2.1.0
pkgrel=1
pkgdesc="3rd party drivers for INDI, a distributed control protocol designed to operate astronomical instrumentation"
provides=("libindi_3rdparty")
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL2.1)
arch=(i686 x86_64 armv7h aarch64)
depends=(libvorbis libusb openal libnova libjpeg libindi libgphoto2 libftdi-compat libdc1394 cfitsio dcraw libftdi rtl-sdr gpsd ffmpeg libindi_3rdparty_libs=${pkgver})
makedepends=(cmake boost)
conflicts=()
source=("https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz")
sha256sums=("c2a873d81b718e31c5f5b8d25136fdfe19b2e21f420d67b270c65acfe5a5d313")

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DFIRMWARE_INSTALL_DIR=/usr/lib/firmware \
    -DBUILD_LIBS=Off \
    -DWITH_ASICAM=On \
    -DWITH_EQMOD=On \
    -DWITH_TOUPBASE=On \
    -DWITH_GPSD=On \
    ../indi-3rdparty-${pkgver}
  make -j$(nproc)
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
  cd "$pkgdir"
  cp -a lib/* usr/lib/
  rm -rf lib/*
  rmdir lib
}