# Maintainer: Stijn Buys <ingar@telenet.be>
# Contributor: Marc-Olivier Barre <mobarre-archlinux@snarchi.io>
# Contributor: Peter Strapp <peter@strapp.co.uk>

# TODO
# 	create indi user and home directory

pkgname=libindi_3rdparty
pkgver=2.1.5.1
pkgrel=1
pkgdesc="3rd party drivers for INDI, a distributed control protocol designed to operate astronomical instrumentation"
provides=("libindi_3rdparty")
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL2.1)
arch=(x86_64 aarch64)
depends=(libvorbis libusb openal libnova libjpeg libindi libgphoto2 libftdi-compat libdc1394 cfitsio dcraw libftdi rtl-sdr gpsd ffmpeg libindi_3rdparty_libs=${pkgver})
makedepends=(cmake boost)
conflicts=()
source=(
	"https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz"
	"indiserver.conf"
	"indiserver.service"
	"indiserver_systemd"
	"CMakeCommon.cmake"
)
sha256sums=(
	"9a85e6cf928dd095f019adf1919c79f9a3ac55294bedb8c9f65cc8bf3f9152d8"
	"6784118f7826c563058711bc3336d877ca44e79cf8b7e5205ab00901b1892924"
	"3f909377d938217e545f1a4538738bbdbdbebf66ecc2a38a2194c46255bf5518"
	"64b0197fd6296c201516e5f81e1edc4b4415e3d80663c3533c9ed249ab844d6a"
	"a7c0c7d933a5bbdba24c360c56e8dd100a622641e6b13dd7481d5268ea44f332"
)
backup=(etc/indiserver.conf)

prepare() {
  mkdir -p build
  cp CMakeCommon.cmake indi-3rdparty-${pkgver}/cmake_modules/
}

build() {
  cd build
  cmake \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DFIRMWARE_INSTALL_DIR=/usr/lib/firmware \
    -DBUILD_LIBS=Off \
    -DWITH_ASICAM=On \
    -DWITH_EQMOD=On \
    -DWITH_TOUPBASE=On \
    -DWITH_GPSD=On \
    ../indi-3rdparty-${pkgver}
  make -j$(nproc)
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
  
  cd "${pkgdir}"
  install -d "etc/"
  install -m 644 "${srcdir}/indiserver.conf" "etc/indiserver.conf"
 
  install -d "usr/lib/systemd/system/"
  install -m 644 "${srcdir}/indiserver.service" "usr/lib/systemd/system/indiserver.service"
  
  install -d "usr/bin/"
  install -m 755 "${srcdir}/indiserver_systemd" "usr/bin/indiserver_systemd"

  cp -a lib/* usr/lib/
  rm -rf lib/*
  rmdir lib
}