# Maintainer: Stijn Buys <ingar@telenet.be>
# Contributor: Marc-Olivier Barre <mobarre-archlinux@snarchi.io>
# Contributor: Peter Strapp <peter@strapp.co.uk>

# TODO
# 	create indiserver user and /var/lib/indiserver directory

pkgname=indi-3rdparty-drivers
pkgver=2.1.9
pkgrel=1
pkgdesc="3rd party drivers for INDI, a distributed control protocol designed to operate astronomical instrumentation"
provides=("libindi_3rdparty")
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL2.1)
arch=(x86_64 aarch64)
depends=(libvorbis libusb openal libnova libjpeg libindi libgphoto2 libftdi-compat libdc1394 cfitsio dcraw libftdi rtl-sdr gpsd ffmpeg libindi_3rdparty_libs=${pkgver})
makedepends=(cmake)
conflicts=()
source=(
        "indi-3rdparty-${pkgver}.tar.gz::https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz"
	"indiserver.conf"
	"indiserver.service"
	"indiserver_systemd"
)
sha256sums=(
	"4c9bbd6864175b1384c5aaf1bb21ca6ec3e95189ee900231b77e0a7b9c5cae16"
	"6784118f7826c563058711bc3336d877ca44e79cf8b7e5205ab00901b1892924"
	"3f909377d938217e545f1a4538738bbdbdbebf66ecc2a38a2194c46255bf5518"
	"64b0197fd6296c201516e5f81e1edc4b4415e3d80663c3533c9ed249ab844d6a"
)
backup=(etc/indiserver.conf)

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DFIRMWARE_INSTALL_DIR=/usr/lib/firmware \
    -DBUILD_LIBS=Off \
    -DWITH_ASICAM=On \
    -DWITH_EQMOD=On \
    -DWITH_GPSD=On \
    ../indi-3rdparty-${pkgver}
  make -j$(nproc)
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
  
  cd "${pkgdir}"
  install -d "etc/"
  install -m 644 "${srcdir}/indiserver.conf" "etc/indiserver.conf"
 
  install -d "usr/lib/systemd/system/"
  install -m 644 "${srcdir}/indiserver.service" "usr/lib/systemd/system/indiserver.service"
  
  install -d "usr/bin/"
  install -m 755 "${srcdir}/indiserver_systemd" "usr/bin/indiserver_systemd"

  cp -a lib/* usr/lib/
  rm -rf lib/*
  rmdir lib
}