# Maintainer: Stijn Buys <ingar@telenet.be>
# Contributor: Marc-Olivier Barre <mobarre-archlinux@snarchi.io>
# Contributor: Peter Strapp <peter@strapp.co.uk>

pkgname=indi-3rdparty-drivers
pkgver=2.1.9
pkgrel=2
pkgdesc="3rd party drivers for INDI, a distributed control protocol designed to operate astronomical instrumentation"
provides=("libindi_3rdparty")
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL2.1)
arch=(x86_64 aarch64)
depends=(libvorbis libusb openal libnova libjpeg libindi libgphoto2 libftdi-compat libdc1394 cfitsio dcraw libftdi rtl-sdr gpsd ffmpeg indi-3rdparty-libs)
makedepends=(cmake)
conflicts=()
source=(
        "indi-3rdparty-${pkgver}.tar.gz::https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz"
)
sha256sums=(
	"4c9bbd6864175b1384c5aaf1bb21ca6ec3e95189ee900231b77e0a7b9c5cae16"
)

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DFIRMWARE_INSTALL_DIR=/usr/lib/firmware \
    -DBUILD_LIBS=Off \
    -DWITH_ASICAM=On \
    -DWITH_EQMOD=On \
    -DWITH_GPSD=On \
    ../indi-3rdparty-${pkgver}
  make -j$(nproc)
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
  
  cd "${pkgdir}"
  cp -a lib/* usr/lib/
  rm -rf lib/*
  rmdir lib
}